home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Libris Britannia 4
/
science library(b).zip
/
science library(b)
/
HAM_RAD
/
PROPAGAT
/
1004A.ZIP
/
TROPS.BAS
< prev
next >
Wrap
BASIC Source File
|
1987-05-12
|
4KB
|
76 lines
15 PRINT CHR$(26): REM ORIGINAL PROGRAM BY MIKE MOREKEN, TSC 2/84
20 PRINT " *********************************************
30 PRINT " * *
40 PRINT " * BY DR. ALLEN KATZ, CHAIRMAN *
50 PRINT " * DEPT ELECTRONICS ENGINEERING TECHNOLOGY *
60 PRINT " * TRENTON STATE COLLEGE, CN550 *
70 PRINT " * TRENTON, NEW JERSEY 8625 *
80 PRINT " * *
90 PRINT " * THE AUTHOR RESERVES RIGHTS TO THIS *
100 PRINT " * PROGRAM; HOWEVER, COPYING AND USE FOR *
110 PRINT " * EDUCATIONAL PURPOSES IS ENCOURAGED. *
120 PRINT " * *
130 PRINT " * PLEASE REPORTS ANY ERRORS OR PROBLEMS *
140 PRINT " * WITH THIS PROGRAM TO THE AUTHOR. *
150 PRINT " * TEL (609) 771 2487 *
160 PRINT " * *
170 PRINT " *********************************************
180 R=6371.4: PI=4*ATN(1): REM 1 KM=.62137 MILES: R=EARTH RADIUS IN KM
185 PRINT: PRINT "TROPOSCATTER PATH LOSS PROGRAM V1.0M 2/2/86"
220 PRINT: PRINT "PLEASE ENTER THE FREQUENCY IN MHz AND ALL ANGLES IN DEGREES "
230 PRINT :INPUT"DO YOU WISH TO USE THE ENGLISH OR METRIC SYSTEM (E/M)";A$: PRINT CHR$(26)
240 IF A$="M" THEN Q$=" IN METERS"
250 IF A$="M" THEN R$=" IN KILOMETERS"
260 IF A$="E" THEN Q$=" IN FEET"
270 IF A$="E" THEN R$=" IN MILES"
280 REM**********TX****************
290 INPUT"IS THERE AN OBSTRUCTION BETWEEN THE TX AND HORIZON (Y/N)";O$
300 IF O$="N" THEN AA=0:IF AA=0 THEN 400
310 PRINT "WHAT IS THE TX HEIGHT";Q$:INPUT T1
320 IF T1<0 THEN 310
330 PRINT "WHAT IS THE HEIGHT OF THE TX OBSTRUCTION";Q$:INPUT T2
340 IF T2 <0 THEN 330
350 IF T2<T1 THEN PRINT "YOU HAVE ENTERED A NEGATIVE HORIZON"
360 PRINT "WHAT IS THE DISTANCE BETWEEN THE TX & OBSTRUCTION";R$:INPUT D1
370 IF D1<=0 THEN 360
380 REM*********RX******************
390 PRINT CHR$(26);
400 INPUT"IS THERE AN OBSTRUCTION BETWEEN THE RX AND HORIZON (Y/N)";P$
410 IF P$="N" THEN AB=0:IF AB=0 THEN 490
420 PRINT :PRINT "NOW THE RECEIVING END":PRINT "WHAT IS THE RX HEIGHT";Q$:INPUT T3
430 IF T3<0 THEN 350
440 PRINT "HEIGHT OF THE OBSTRUCTION IN PATH OF RX";Q$:INPUT T4
450 IF T4<0 THEN 440
460 PRINT "WHAT IS THE DISTANCE BETWEEN THIS OBSTRUCTION & THE RX";R$
470 INPUT D2
480 IF D2<=0 THEN 460
490 PRINT "WHAT IS THE DISTANCE BETWEEN THE RX & TX";R$:INPUT D3
500 IF (D1+D2)>D3 THEN 490
510 INPUT"WHAT IS THE FREQUENCY IN MHz";F
520 INPUT"WHAT IS THE BEAMWIDTH OF THE RX ANTENNA IN DEGREES";BR
530 INPUT"WHAT IS THE BEAMWIDTH OF THE TX ANTENNA IN DEGREES";BT
540 PRINT "THE REFRACTIVE INDEX TYPICALLY VARIES BETWEEN 250 & 400"
550 INPUT"WHAT IS THE REFRACTIVE INDEX";N
560 IF N<100 OR N>500 THEN 540
570 IF A$="M" THEN K=1 ELSE K=.3048
580 T1=K*T1:T2=K*T2:T3=K*T3:T4=K*T4
590 IF A$="M" THEN L=1 ELSE L=1.6093
600 D1=L*D1:D2=L*D2:D3=L*D3
610 IF D1=0 THEN 640
620 A5=(T2-T1)/(1000*D1):A6=D1/(2*R)
630 AA=(A5-A6)*(180/PI)
640 IF D2=0 THEN 670
650 B5=(T4-T3)/(1000*D2):B6=D2/(2*R)
660 AB=(B5-B6)*(180/PI)
670 AC=(D3/R)*(180/PI)
680 AS=AC+AA+AB
690 FS=32.5+(20*LOG(D3)/LOG(10))+(20*LOG(F)/LOG(10))
700 SC=21+10*AS+10*LOG(F)/LOG(10)
710 AO=(2*AS/((BR*BT)^.5)):AP=AO+2
720 RI=.2*(310-N)
730 TL=55.5+20*LOG(D3)/LOG(10)+30*LOG(F)/LOG(10)+AO+RI
740 PRINT CHR$(26);
750 PRINT :PRINT :PRINT :PRINT :PRINT :PRINT :PRINT :PRINT TAB(22);"THE TOTAL LOSS IS";TL" dB"
760 PRINT :PRINT :PRINT :PRINT :PRINT :INPUT "WANT TO TRY AGAIN (Y/N)";Y$:IF Y$="Y" THEN PRINT CHR$(26): GOTO 290
770 END